Flash 8 ActionScript 2.0 Language Reference

Class AsBroadcaster

Object

There is no constructor function for the AsBroadcaster class. To use this class, follow this process:

• Select or create an object to serve as the event broadcaster.
• Make the object an event broadcaster by calling the static AsBroadcaster.initialize(obj:Object) method, where the obj parameter is the name of the object that you selected to be the broadcaster.
• Select or create one or more listener objects. Listener objects receive notification whenever the broadcasting object broadcasts a message
• Define a listener method for each of your listener objects. The listener method executes ActionScript code in response to the event notification. The name of the method must match the name of the event that is broadcasted by the broadcasting object.
• Register each listener object with the event broadcaster by calling myBroadcaster.addListener(myListener), where myBroadcaster is the name of the event broadcaster object and myListener is the name of the listener object. Each event broadcaster stores a list of listener objects to be notified when a message is broadcast. Use the addListener() method to add listeners to the list, and use removeListener() to remove listeners from the list.
• Finally, to broadcast a message, call the myBroadcaster.broadcastMessage(eventName:String) method, where myBroadcaster is the name of the event broadcaster and eventName is the name of the event that matches the name of the listener method.

Note: A common mistake is to capitalize the second letter of AsBroadcaster. When calling the AsBroadcaster.initialize() method, ensure that the second letter is lowercase. Any misspelling of AsBroadcaster fails silently.

_listeners Property

public _listeners : Array  [read-only]

You can call this property only from an object that was initialized by using the AsBroadcaster.initialize() method.

trace(someObject._listeners.length); // Output: 2

For advanced users, the following example shows how to use the _listeners property to list all of the listeners registered with an event broadcaster, along with all of the properties of each listener object. The following example creates two different listener methods for the first listener object.

var someObject:Object = new Object();         // create broadcast object

var myListener1:Object = new Object();        // create listener object
var myListener2:Object = new Object();        // create listener object

myListener1.someEvent = function() {          // create listener method
    trace("myListener1 received someEvent");
}
myListener1.anotherEvent = function() {       // create another listener method
    trace("myListener1 received anotherEvent");
}
myListener2.someEvent = function() {          // create listener method
    trace("myListener2 received someEvent");
}

AsBroadcaster.initialize(someObject);         // make someObject an event broadcaster
someObject.addListener(myListener1);          // register myListener1 as listener
someObject.addListener(myListener2);          // register myListener2 as listener

var numListeners:Number = someObject._listeners.length;  // get number of registered listeners

// cycle through all listener objects, listing all properties of each listener object
for (var i:Number = 0; i < numListeners; i++) {
    trace("Listener " + i + " listens for these events:");
    for (item in someObject._listeners[i]) {
        trace ("   " + item + ": " + someObject._listeners[i][item]);
    }
}

addListener Method

public addListener(listenerObj:Object) : Boolean

someObject.addListener(myListener1);          // Register myListener1 as listener.
someObject.addListener(myListener2);          // Register myListener2 as listener.

broadcastMessage Method

public broadcastMessage(eventName:String) : Void

obj.broadcastMessage("onAlert");

When this message is received, Flash Player invokes a method named onAlert() on the receiving listener object.

Note: You can pass arguments to your listener functions by including additional arguments to the broadcastMessage() method. Any arguments that appear after the eventName parameter are received as arguments by the listener method.

You can call this method only from an object that was initialized by using the AsBroadcaster.initialize() method.

someObject.broadcastMessage("someEvent");     // Broadcast the "someEvent" message.    

The following example is an excerpt from the second full example provided in the entry for the AsBroadcaster.initialize() method. It shows how to send arguments to listener methods.

someObject.broadcastMessage("someEvent", 3, "arbitrary string");

initialize Method

public static initialize(obj:Object) : Void

AsBroadcaster.initialize(someObject);

Note: A common mistake is to capitalize the second letter of AsBroadcaster. When calling the AsBroadcaster.initialize() method, ensure that the second letter is lowercase. Any misspelling of AsBroadcaster will fail silently.

This method adds the _listeners property along with the following three methods to the object specified by the obj parameter:

• obj.addListener()
• obj.removeListener()
• obj.broadcastMessage()

var someObject:Object = new Object();         // Creates broadcast object.

var myListener1:Object = new Object();        // Creates listener object.
var myListener2:Object = new Object();        // Creates listener object.

myListener1.someEvent = function() {          // Creates listener method.
    trace("myListener1 received someEvent");
}
myListener2.someEvent = function() {          // Createz listener method.
    trace("myListener2 received someEvent");
}

AsBroadcaster.initialize(someObject);         // Makes someObject an event broadcaster.
someObject.addListener(myListener1);          // Registers myListener1 as listener.
someObject.addListener(myListener2);          // Registers myListener2 as listener.
someObject.broadcastMessage("someEvent");     // Broadcasts the "someEvent" message.

The following example shows how to pass extra arguments to a listener method by using the broadcastMessage() method. The output should be the three strings shown in the three trace() statements, which also include the arguments passed in through the broadcastMessage() method.

var someObject:Object = new Object();

var myListener:Object = new Object();     
myListener.someEvent = function(param1:Number, param2:String) { 
    trace("myListener received someEvent");
    trace("param1: " + param1);
    trace("param2: " + param2);
}

AsBroadcaster.initialize(someObject);     
someObject.addListener(myListener);          
someObject.broadcastMessage("someEvent", 3, "arbitrary string");

removeListener Method

public removeListener(listenerObj:Object) : Boolean

You can call this method only from an object that has been initialized by using the AsBroadcaster.initialize() method.

trace(someObject._listeners.length);    // Output: 2
someObject.removeListener(myListener1);
trace(someObject._listeners.length);    // Output: 1